new¶

    $http = HTTP::Tiny->new( %attributes );

This constructor returns a new HTTP::Tiny object. Valid attributes include:

• "agent" — A user-agent string (defaults to 'HTTP-Tiny/$VERSION'). If "agent" — ends in a space character, the default user-agent string is appended.
• "cookie_jar" — An instance of HTTP::CookieJar — or equivalent class that supports the "add" and "cookie_header" methods
• "default_headers" — A hashref of default headers to apply to requests
• "local_address" — The local IP address to bind to
• "keep_alive" — Whether to reuse the last connection (if for the same scheme, host and port) (defaults to 1)
• "max_redirect" — Maximum number of redirects allowed (defaults to 5)
• "max_size" — Maximum response size in bytes (only when not using a data callback). If defined, requests with responses larger than this will return a 599 status code.
• "http_proxy" — URL of a proxy server to use for HTTP connections (default is $ENV{http_proxy} — if set)
• "https_proxy" — URL of a proxy server to use for HTTPS connections (default is $ENV{https_proxy} — if set)
• "proxy" — URL of a generic proxy server for both HTTP and HTTPS connections (default is $ENV{all_proxy} — if set)
• "no_proxy" — List of domain suffixes that should not be proxied. Must be a comma-separated string or an array reference. (default is $ENV{no_proxy} —)
• "timeout" — Request timeout in seconds (default is 60) If a socket open, read or write takes longer than the timeout, the request response status code will be 599.
• "verify_SSL" — A boolean that indicates whether to validate the TLS/SSL certificate of an "https" — connection (default is true). Changed from false to true in version 0.083.
• "SSL_options" — A hashref of "SSL_*" — options to pass through to IO::Socket::SSL
• $ENV{PERL_HTTP_TINY_SSL_INSECURE_BY_DEFAULT} - Changes the default certificate verification behavior to not check server identity if set to 1. Only effective if "verify_SSL" is not set. Added in version 0.083.

An accessor/mutator method exists for each attribute.

Passing an explicit "undef" for "proxy", "http_proxy" or "https_proxy" will prevent getting the corresponding proxies from the environment.

Errors during request execution will result in a pseudo-HTTP status code of 599 and a reason of "Internal Exception". The content field in the response will contain the text of the error.

The "keep_alive" parameter enables a persistent connection, but only to a single destination scheme, host and port. If any connection-relevant attributes are modified via accessor, or if the process ID or thread ID change, the persistent connection will be dropped. If you want persistent connections across multiple destinations, use multiple HTTP::Tiny objects.

See "SSL SUPPORT" for more on the "verify_SSL" and "SSL_options" attributes.

get|head|put|post|patch|delete¶

    $response = $http->get($url);
    $response = $http->get($url, \%options);
    $response = $http->head($url);

These methods are shorthand for calling request() for the given method. The URL must have unsafe characters escaped and international domain names encoded. See request() for valid options and a description of the response.

The "success" field of the response will be true if the status code is 2XX.

post_form¶

    $response = $http->post_form($url, $form_data);
    $response = $http->post_form($url, $form_data, \%options);

This method executes a "POST" request and sends the key/value pairs from a form data hash or array reference to the given URL with a "content-type" of "application/x-www-form-urlencoded". If data is provided as an array reference, the order is preserved; if provided as a hash reference, the terms are sorted on key and value for consistency. See documentation for the "www_form_urlencode" method for details on the encoding.

The URL must have unsafe characters escaped and international domain names encoded. See request() for valid options and a description of the response. Any "content-type" header or content in the options hashref will be ignored.

The "success" field of the response will be true if the status code is 2XX.

mirror¶

    $response = $http->mirror($url, $file, \%options)
    if ( $response->{success} ) {
        print "$file is up to date\n";
    }

Executes a "GET" request for the URL and saves the response body to the file name provided. The URL must have unsafe characters escaped and international domain names encoded. If the file already exists, the request will include an "If-Modified-Since" header with the modification timestamp of the file. You may specify a different "If-Modified-Since" header yourself in the "$options->{headers}" hash.

The "success" field of the response will be true if the status code is 2XX or if the status code is 304 (unmodified).

If the file was modified and the server response includes a properly formatted "Last-Modified" header, the file modification time will be updated accordingly.

request¶

    $response = $http->request($method, $url);
    $response = $http->request($method, $url, \%options);

Executes an HTTP request of the given method type ('GET', 'HEAD', 'POST', 'PUT', etc.) on the given URL. The URL must have unsafe characters escaped and international domain names encoded.

NOTE: Method names are case-sensitive per the HTTP/1.1 specification. Don't use "get" when you really want "GET". See LIMITATIONS for how this applies to redirection.

If the URL includes a "user:password" stanza, they will be used for Basic-style authorization headers. (Authorization headers will not be included in a redirected request.) For example:

    $http->request('GET', 'http://Aladdin:open sesame@example.com/');

If the "user:password" stanza contains reserved characters, they must be percent-escaped:

    $http->request('GET', 'http://john%40example.com:password@example.com/');

A hashref of options may be appended to modify the request.

Valid options are:

• "headers" — A hashref containing headers to include with the request. If the value for a header is an array reference, the header will be output multiple times with each value in the array. These headers over-write any default headers.
• "content" — A scalar to include as the body of the request OR a code reference that will be called iteratively to produce the body of the request
• "trailer_callback" — A code reference that will be called if it exists to provide a hashref of trailing headers (only used with chunked transfer-encoding)
• "data_callback" — A code reference that will be called for each chunks of the response body received.
• "peer" — Override host resolution and force all connections to go only to a specific peer address, regardless of the URL of the request. This will include any redirections! This options should be used with extreme caution (e.g. debugging or very special circumstances). It can be given as either a scalar or a code reference that will receive the hostname and whose response will be taken as the address.

The "Host" header is generated from the URL in accordance with RFC 2616. It is a fatal error to specify "Host" in the "headers" option. Other headers may be ignored or overwritten if necessary for transport compliance.

If the "content" option is a code reference, it will be called iteratively to provide the content body of the request. It should return the empty string or undef when the iterator is exhausted.

If the "content" option is the empty string, no "content-type" or "content-length" headers will be generated.

If the "data_callback" option is provided, it will be called iteratively until the entire response body is received. The first argument will be a string containing a chunk of the response body, the second argument will be the in-progress response hash reference, as described below. (This allows customizing the action of the callback based on the "status" or "headers" received prior to the content body.)

Content data in the request/response is handled as "raw bytes". Any encoding/decoding (with associated headers) are the responsibility of the caller.

The "request" method returns a hashref containing the response. The hashref will have the following keys:

• "success" — Boolean indicating whether the operation returned a 2XX status code
• "url" — URL that provided the response. This is the URL of the request unless there were redirections, in which case it is the last URL queried in a redirection chain
• "status" — The HTTP status code of the response
• "reason" — The response phrase returned by the server
• "content" — The body of the response. If the response does not have any content or if a data callback is provided to consume the response body, this will be the empty string
• "headers" — A hashref of header fields. All header field names will be normalized to be lower case. If a header is repeated, the value will be an arrayref; it will otherwise be a scalar string containing the value
• "protocol" - If this field exists, it is the protocol of the response such as HTTP/1.0 or HTTP/1.1
• "redirects" If this field exists, it is an arrayref of response hash references from redirects in the same order that redirections occurred. If it does not exist, then no redirections occurred.

On an error during the execution of the request, the "status" field will contain 599, and the "content" field will contain the text of the error.

www_form_urlencode¶

    $params = $http->www_form_urlencode( $data );
    $response = $http->get("http://example.com/query?$params");

This method converts the key/value pairs from a data hash or array reference into a "x-www-form-urlencoded" string. The keys and values from the data reference will be UTF-8 encoded and escaped per RFC 3986. If a value is an array reference, the key will be repeated with each of the values of the array reference. If data is provided as a hash reference, the key/value pairs in the resulting string will be sorted by key and value for consistent ordering.

can_ssl¶

    $ok         = HTTP::Tiny->can_ssl;
    ($ok, $why) = HTTP::Tiny->can_ssl;
    ($ok, $why) = $http->can_ssl;

Indicates if SSL support is available. When called as a class object, it checks for the correct version of Net::SSLeay and IO::Socket::SSL. When called as an object methods, if "SSL_verify" is true or if "SSL_verify_mode" is set in "SSL_options", it checks that a CA file is available.

In scalar context, returns a boolean indicating if SSL is available. In list context, returns the boolean and a (possibly multi-line) string of errors indicating why SSL isn't available.

connected¶

    $host = $http->connected;
    ($host, $port) = $http->connected;

Indicates if a connection to a peer is being kept alive, per the "keep_alive" option.

In scalar context, returns the peer host and port, joined with a colon, or "undef" (if no peer is connected). In list context, returns the peer host and port or an empty list (if no peer is connected).

Note: This method cannot reliably be used to discover whether the remote host has closed its end of the socket.

Bugs / Feature Requests¶

Please report any bugs or feature requests through the issue tracker at <https://github.com/Perl-Toolchain-Gang/HTTP-Tiny/issues>. You will be notified automatically of any progress on your issue.

Source Code¶

This is open source software. The code repository is available for public review and contribution under the terms of the license.

<https://github.com/Perl-Toolchain-Gang/HTTP-Tiny>

  git clone https://github.com/Perl-Toolchain-Gang/HTTP-Tiny.git