type¶

Either "ipv4", "ipv6" or the name of a coder class.

See Net::CIDR::Set::IPv4 and Net::CIDR::Set::IPv6 for examples of coder classes.

new¶

Create a new Net::CIDR::Set. All arguments are optional. May be passed a list of list of IP addresses or ranges which, if present, will be passed to "add".

The first argument may be a hash reference which will be inspected for named options. Currently the only option that may be passed is "type".

invert¶

Invert (negate, complement) a set in-place.

  my $set = Net::CIDR::Set->new;
  $set->invert;

copy¶

Make a deep copy of a set.

  my $set2 = $set->copy;

add¶

Add a number of addresses or ranges to a set.

  $set->add(
    '10.0.0.0/8',
    '192.168.0.32-192.168.0.63',
    '127.0.0.1'
  );

It is legal to add ranges that overlap with each other and/or with the ranges already in the set. Overlapping ranges are merged.

remove¶

Remove a number of addresses or ranges from a set.

  $set->remove(
    '8.8.0.0/16',
    '158.152.1.58'
  );

There is no requirement that the addresses being removed be members of the set.

merge¶

Merge the contents of other sets into this set.

  $set = Net::CIDR::Set->new;
  $set->merge($s1, $s2);

contains¶

A synonym for "contains_all".

contains_all¶

Return true if the set contains all of the supplied addresses. Given this set:

  my $set = Net::CIDR::Set->new('244.188.12.0/12');

this condition is true:

  if ( $set->contains_all('244.188.12.128/32') ) {
    # ...
  }

while this condition is false:

  if ( $set->contains_all('244.188.12.0/8') ) {
    # ...
  }

contains_any¶

Return true if there is any overlap between the supplied addresses/ranges and the contents of the set.

complement¶

Return a new set that is the complement of this set.

  my $inv = $set->complement;

union¶

Return a new set that is the union of a number of sets. This is equivalent to a logical OR between sets.

  my $everything = $east->union($west);

intersection¶

Return a new set that is the intersection of a number of sets. This is equivalent to a logical AND between sets.

  my $overlap = $north->intersection($south);

xor¶

Return a new set that is the exclusive-or of existing sets.

  my $xset = $this->xor($that);

The resulting set will contain all addresses that are members of one set but not the other.

diff¶

Return a new set containing all the addresses that are present in this set but not another.

  my $diff = $this->diff($that);

is_empty¶

Return a true value if the set is empty.

  if ( $set->is_empty ) {
    print "Nothing there!\n";
  }

superset¶

Return true if this set is a superset of the supplied set.

subset¶

Return true if this set is a subset of the supplied set.

equals¶

Return true if this set is identical to another set.

  if ( $set->equals($foo) ) {
    print "We have the same addresses.\n";
  }

iterate_addresses¶

Return an iterator (a closure) that will return each of the addresses in the set in ascending order. This code

  my $set = Net::CIDR::Set->new('192.168.37.0/24');
  my $iter = $set->iterate_addresses;
  while ( my $ip = $iter->() ) {
    print "Got $ip\n";
  }

outputs 256 distinct addresses from 192.168.37.0 to 192.168.27.255.

iterate_cidr¶

Return an iterator (a closure) that will return each of the CIDR blocks in the set in ascending order. This code

  my $set = Net::CIDR::Set->new('192.168.37.9-192.168.37.134');
  my $iter = $set->iterate_cidr;
  while ( my $cidr = $iter->() ) {
    print "Got $cidr\n";
  }

outputs

  Got 192.168.37.9
  Got 192.168.37.10/31
  Got 192.168.37.12/30
  Got 192.168.37.16/28
  Got 192.168.37.32/27
  Got 192.168.37.64/26
  Got 192.168.37.128/30
  Got 192.168.37.132/31
  Got 192.168.37.134

This is the most compact CIDR representation of the set because its limits don't fall on convenient CIDR boundaries.

iterate_ranges¶

Return an iterator (a closure) that will return each of the ranges in the set in ascending order. This code

  my $set = Net::CIDR::Set->new(
    '192.168.37.9-192.168.37.134',
    '127.0.0.1',
    '10.0.0.0/8'
  );
  my $iter = $set->iterate_ranges;
  while ( my $range = $iter->() ) {
    print "Got $range\n";
  }

outputs

  Got 10.0.0.0/8
  Got 127.0.0.1
  Got 192.168.37.9-192.168.37.134

as_array¶

Convenience method that gathers all of the output from one of the iterators above into an array.

  my @ranges = $set->as_array( $set->iterate_ranges );

Normally you will use one of "as_address_array", "as_cidr_array" or "as_range_array" instead.

as_address_array¶

Return an array containing all of the distinct addresses in a set. Note that this may very easily create a very large array. At the time of writing it is, for example, unlikely that you have enough memory for an array containing all of the possible IPv6 addresses...

as_cidr_array¶

Return an array containing all of the distinct CIDR blocks in a set.

as_range_array¶

Return an array containing all of the ranges in a set.

as_string¶

Return a compact string representation of a set.

Reporting Security Vulnerabilities¶

If the bug you are reporting has security implications which make it inappropriate to send to a public issue tracker, then see SECURITY.md for instructions how to report security vulnerabilities.